Passing a Temporary Record to/from a Dataport?

Joe Cool · **Posted:** Wed Aug 09, 2006 10:08 pm

Hello Everyone,
I was wondering if you can pass a temporary table to a dataport for export.

I have tried it by including the following line in a codeunit that contain a function that populates the temp table with the desired records;

Quote:

DATAPORT.RUNMODAL(50066,TRUE,gtbUNIINSmallParcel);

but I get an error message when it tried to execute telling me that the dataport does not have a DataItem that uses the table specified in the function SetTableView.
The Dataport has the table listed in the dataitem and it is the same table the temp record is based on.

So why am I getting this error? Can this even be done? I am trying to do with through a temp table so that I do not have to create a new table that is similar to one that I have already created that has the fields that I need. I know that I can use variables in the dataport to include values contained in various tables, but that would mean that I would have to use coded logic to filter the records rather than true filters and therefore would have to scan the entire table everytime I run the report.

If remove the temp table from the RUNMODAL command there is no error (but the dataport uses the data that is in the table - Obviously).

Joe
P.S. I know that isn't the Canadian flag... I just thought I would use my Ethnic flag instead of my residence flag.

David Cox · **Posted:** Wed Aug 09, 2006 10:18 pm

you will have to pass in the recordset and populate the export from the passed in table.

I would use an integer and variables to export

Joe Cool · **Posted:** Wed Aug 09, 2006 11:02 pm

David Cox wrote:

you will have to pass in the recordset and populate the export from the passed in table.

I would use an integer and variables to export

Thanks for the reply, but I don't understand what you are saying.
I guess that I should have mentioned that I am a Navision Newbie.
I thought I was passing the recordset in the RUNMODAL command.

gtbUNIINSmallParcel = the Temp Record that is populated in the Codeunit.
50066 = the Dataport.

kriki · **Posted:** Thu Aug 10, 2006 8:29 am

In the dataport, you need to make a global record variable "tmpTheTempTable" as temptable (property Temptable=Yes).
The dataitem of your dataport must work on the virtual table integer. In the dataportfields, you have to put the fields of the temptable.
You need a function in your dataport to fill up the temptable. Something like:

Code: Select all

Function ImportTempTable (VAR ItmpTheTempTable : as temptable)
ItmpTheTempTable.RESET;
IF ItmpTheTempTable.FIND('-') THEN
  REPEAT
    tmpTheTempTable := ItmpTheTempTable;
    tmpTheTempTable.INSERT(FALSE);
  UNTIL ItmpTheTempTable.NEXT = 0;

In the OnPreDataItem-trigger:

Code: Select all

tmpTheTempTable.RESET;
SETRANGE(Number,1,tmpTheTempTable.COUNT);

In the OnBeforeExportRecord-trigger:

Code: Select all

IF Number = 1 THEN
  tmpTheTempTable.FIND('-')
ELSE
  tmpTheTempTable.NEXT;

In the calling program:
Make a global variable for the dataport
For calling the dataport:

Code: Select all

CLEAR(dtpYourDataport);
dtpYourDataport.ImportTempTable(tmpTheTempTable);
dtpYourDataport.RUNMODAL;

Joe Cool · **Posted:** Thu Aug 10, 2006 7:42 pm

Thanks.
I didn't know that you could set a DataItem entered as Integer and what that did. Once I figured that out, I realized that I could contain all the code and the temporay table within the dataport.

Joe

AST · **Posted:** Fri Nov 09, 2007 8:17 pm

What about import to temporary table? What is the trick?

kriki · **Posted:** Sat Nov 10, 2007 3:39 pm

AST wrote:

What about import to temporary table? What is the trick?

Less or more the same.
You put the table on which your temptable is based in the dataitem with properties AutoSave,AutoUpdate,AutoReplace = No.

global:
tmpTheTable as TEMPORARY record

OnBeforeImportRecord-trigger:

Code: Select all

CLEAR("The Table");

OnAfterImportRecord-trigger:

Code: Select all

tmpTheTable := "The Table";
tmpTheTable.INSERT(FALSE);

This function must be called after launching the dataport:

Code: Select all

Function ExportTempTable (VAR OtmpTheTempTable : as temptable)
OtmpTheTempTable.RESET;
OtmpTheTempTable.DELETEALL(FALSE);

tmpTheTable.RESET;
IF tmpTheTable.FIND('-') THEN
  REPEAT
    OtmpTheTempTable := tmpTheTable;
    OtmpTheTempTable.INSERT(FALSE);
  UNTIL tmpTheTable.NEXT = 0;

kriki · **Posted:** Sat Nov 10, 2007 3:41 pm

[Topic moved from Navision Attain forum to Navision Tips & Tricks forum]
[Changed the title from "[SOLVED] Passing a Temporary Record to a Dataport?" to "[SOLVED] Passing a Temporary Record to/from a Dataport?"]

Ravi_Thakkar · **Posted:** Fri Jun 17, 2011 8:06 am

Hello Kriki,

Thanks for your great Tip regarding "Import Data in Temporary Table through Dataport".
I have did the code as you have suggested for the same task.

I wrote one codeunit as below.

Code: Select all

OnRun()
LocationDtp.RUNMODAL;
LocationDtp.ExportTempTable(LocationTmpTable);
LocationListFrm.SETTABLEVIEW(LocationTmpTable);
LocationListFrm.RUNMODAL;

Where variables are:
LocationDtp-Dataport-Location
LocationListFrm-Form-Location List
LocationTmpTable-Record-Location-Temporary=yes.

Dataport "Location" with properties AutoSave,AutoUpdate,AutoReplace = No.
having code as:

Code: Select all

Documentation()
Location - OnPreDataItem()
Location - OnBeforeExportRecord()
Location - OnAfterExportRecord()
Location - OnBeforeImportRecord()
CLEAR(Location);

Location - OnAfterImportRecord()
LocTmp := Location;
LocTmp.INSERT(FALSE);

Location - OnPostDataItem()

ExportTempTable(VAR OtmpTheTempTable : TEMPORARY Record Location)OtmpTheTempTable.RESET;
OtmpTheTempTable.DELETEALL(FALSE);

LocTmp.RESET;
IF LocTmp.FIND('-') THEN
  REPEAT
    OtmpTheTempTable := LocTmp;
    OtmpTheTempTable.INSERT(FALSE);
  UNTIL LocTmp.NEXT = 0;

Where variables are:
Parameters of ExportTempTable Function:
Var-Name-DataType-Subtype
Yes-OtmpTheTempTable-Record-Location

Global Variables:
Name-DataType-Subtype
LocTmp-Record-Location
LocationListFrm-Form-Location List

After I run the Codeunit, it is now viewing the Temporary Table Data in the form.
It is working fine now.

Thanks for sharing such a gr8 tip.

kriki · **Posted:** Mon Jun 20, 2011 10:04 am

It's nice to see that my tips are put to good use!

Ravi_Thakkar · **Posted:** Mon Jun 20, 2011 10:19 am

True Kriki.

I am having an issue in the same method with the XML PORT in RTC.

ExportTempTable returns Blank table from the XML PORT.

I think XMLport does not run Modally, and that's why I am facing the issue.
Any suggestion regarding the same?

kriki · **Posted:** Mon Jun 20, 2011 5:38 pm

Have you tried the XML-port with a classic client? Just to be sure it is a RTC problem and not something else.

Belias · **Posted:** Tue Jun 21, 2011 10:43 am

i just made a test xmlport (used as dataport) (--> sorry, it is a real xmlport, not an xmlport as dataport) that works like a charm, using the temporary property of the table element.
I did it while testing webservices and see where i can go

Code: Select all

OBJECT XMLport 50600 xmlwebservice
{
  OBJECT-PROPERTIES
  {
    Date=20/06/11;
    Time=17.55.33;
    Modified=Yes;
    Version List=;
  }
  PROPERTIES
  {
    UseDefaultNamespace=Yes;
    OnPostXMLport=BEGIN
                    ERROR(FORMAT(Location.COUNT));
                  END;

  }
  ELEMENTS
  {
    { [{80D3A770-4659-442E-890D-16964E055A84}];  ;RootLocation        ;Element ;Text    ;
                                                  MaxOccurs=Once }

    { [{E06FC085-52D9-4301-A107-15DC5822CD34}];1 ;Location            ;Element ;Table   ;
                                                  SourceTable=Table14;
                                                  Temporary=Yes }

    { [{9E0DD462-6DDC-4D68-9435-BDC5FBE21631}];2 ;Code                ;Element ;Field   ;
                                                  DataType=Code;
                                                  SourceField=Location::Code }

    { [{A921CED9-96DF-4FD3-A6AD-8C12D2A114C6}];2 ;Name                ;Element ;Field   ;
                                                  DataType=Text;
                                                  SourceField=Location::Name }

  }
  EVENTS
  {
  }
  REQUESTPAGE
  {
    PROPERTIES
    {
    }
    CONTROLS
    {
    }
  }
  CODE
  {

    BEGIN
    END.
  }
}

mibuso.com

Passing a Temporary Record to/from a Dataport?

Who is online